UWSC｜配列要素の削除と挿入・追加【参照渡し使用】

左側のメインから右側の関数へ引数を渡しますが、渡し方に“値渡し”と“参照渡し”（C++と同じものと思ってもいいのかな？）があります。

値渡し

関数へはメインのローカル変数Aの値を教えて、関数内RESULTの値をメインのローカル変数Bに代入します。

このとき、関数は変数Aの値を教えてもらってるだけなので、関数内からはメインの変数Aを一切更新することができません。

参照渡し

関数へはメインのローカル変数Aそのものを渡して（在り処を教えてる？）、関数内RESULTの値をメインのローカル変数Bに代入します。

このとき、関数はメインのローカル変数Aそのものを預かっている（に等しい）ので、関数内で引数Cを更新すると、メインのローカル変数である変数Aも更新されてしまいます。

この参照渡しを実現するには、関数の宣言文FUNCTIONでの引数の定義を“var 引数”とします。

WindowsPC倍速・時短テクニックユーザー・ハンドブック

Amazon

楽天市場

通常は値渡しを使用。でも都合の悪い場合＝「戻り値が配列、かつ、要素数が関数内で変化してしまった場合」が存在。

UWSCでは下の一文書くだけで関数の戻り配列が全要素コピーされます。

今回の目的は配列の再構築＝要素の削除、挿入・追加→関数を通る前後で要素数が変化。その場合、「要素数が違うよ」とエラーが出て止まってしまいます。

そこで、この“参照渡し”を使用し、呼び出し側が一行で済むように作ります。

FUNCTION remove(var a[],rn)
   IF rn<0 or rn>LENGTH(a)-1
            PRINT "ポクエラー(remove関数)：無効な要素番号が削除指定されました。"
            RESULT=0
   ELSE
      FOR i=rn TO LENGTH(a)-1-1
            a[i]=a[i+1]
      NEXT
            RESIZE(a,LENGTH(a)-1-1)
            RESULT=1
   ENDIF
FEND

FUNCTION append(var a[],an,dt)
            RESIZE(a,LENGTH(a)-1+1)
   IF an<0 or an>LENGTH(a)-1
            a[LENGTH(a)-1]=dt
   ELSE
      FOR i=LENGTH(a)-1 TO an step -1
         IF i=an
            a[i]=dt
         ELSE
            a[i]=a[i-1]
         ENDIF
      NEXT
   ENDIF
            RESULT=1
FEND

動作確認用プログラムがこちら。

   DIM test[10]
FOR i=0 TO LENGTH(test)-1
   test[i]=i*2
   PRINT test[i]
NEXT
   PRINT "--最大要素番号は"+LENGTH(test)-1

   rn=8
   remove(test,rn)
   PRINT "--要素"+rn+"を削除"
FOR i=0 TO LENGTH(test)-1
   PRINT test[i]
NEXT
   PRINT "--最大要素番号は"+LENGTH(test)-1

   an=5
   dt=51
   append(test,an,dt)
   PRINT "--要素"+an+"に"+dt+"を追加"
FOR i=0 TO LENGTH(test)-1
   PRINT test[i]
NEXT
   PRINT "--最大要素番号は"+LENGTH(test)-1

動作確認結果がこちら。

0
2
4
6
8
10
12
14
16
18
20
--最大要素番号は10
--要素8を削除
0
2
4
6
8
10
12
14
18
20
--最大要素番号は9
--要素5に51を追加
0
2
4
6
8
51
10
12
14
18
20
--最大要素番号は10

要素8を削除すると、test[8]の16が無くなり最大要素番号が一つ小さく9となります。

要素5に51を追加すると、test[5]に51が代入、以降は後ろへ一つづつずれて、最大要素番号が一つ大きい10になってくれました。

8、16行目の値を変更して試してみてください。